source: trunk/superstring/SConstruct @ 812

# #############################################################################
# SConstruct: SCons build instructions
#
# Copyright 2006-2007 Chip Norkus
# See the COPYING file for more information on licensing and use.
#
# $Id$
#
# #############################################################################

###############################################################################
# Initial setup (Python path tweaks etc)

package_name = "superstring"
package_version = "1.0"

EnsurePythonVersion(2,2)
EnsureSConsVersion(0,96,92)

import glob, os, sys
# let's just stick the realpath() for ./build in there at the front.  THis
# allows us to use our custom test code in the 'tests' module there.
sys.path.insert(0, os.path.realpath('./build'))
import tests

###############################################################################
# Global environment setup.  Import the user's $PATH for our own sanity.
env = Environment(ENV = {
    'PATH': os.environ['PATH'],
    },
    CPPPATH = ['#/include']
)

###############################################################################
# Options

opts = Options(None, ARGUMENTS)
opts.AddOptions(
# Other path options are handled below 
    PathOption('prefix', 'Installation prefix', '/usr/local',
        tests.PathIsDirCreateAccess),
)
opts.Update(env)

# Okay, let's make some dumb guesses:  If the name already contains
# 'package' in it let's go ahead and not add that again.  If the name is
# standard (/usr, /usr/local, /opt) let's add it there.  Other than that we
# aren't too smart. :)
if env['prefix'] == '/usr' or env['prefix'] == '/opt':
    # /usr and /opt need special handling to stuff things in /etc
    sysconfdir = '/etc'
else:
    sysconfdir = env['prefix'] + '/etc'

dir_suffix = ''
if not package_name in env['prefix']:
    dir_suffix = '/' + package_name

opts.AddOptions(
    BoolOption('debug', 'Enable creation of debugging symbols', 0),
    BoolOption('warnings', 'Compile with aggressive warning checks', 1),
    PathOption('libdir', "Library installation directory",
        env['prefix'] + '/lib' + dir_suffix, tests.PathIsDirCreateAccess),
    PathOption('includedir', 'C header installation directory',
        env['prefix'] + '/include', tests.PathIsDirCreateAccess),
)
opts.Update(env)

env.Help(opts.GenerateHelpText(env))

###############################################################################
# Configuration tests
conf = env.Configure(config_h = 'include/config.h',
    custom_tests = tests.tests)

conf.CheckCCompiler()
conf.CheckCVersion()

# Set compiler options
if env['CC'] == 'gcc':
    if env['debug']:
        env.AppendUnique(CCFLAGS = ['-O', '-g3'])
    if env['warnings']:
        env.AppendUnique(CCFLAGS = Split('''
            -Wall -Wshadow -Wmissing-declarations -Wpointer-arith -Wcast-align
            -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations
            -Wredundant-decls -Winline -Wbad-function-cast
            '''))

conf.Finish()

###############################################################################
# Build options and subsidiary code

env.Export(['env', 'tests'])

env.Install(env['includedir'] + '/superstring',
    glob.glob('include/superstring/*.h'))

# dummy install target with our various prefixes.
env.Alias('install', env['libdir'], env['includedir'])

# and call our sub-scripts.
env.SConscript('source/SConscript')

# vi:set ts=8 sts=4 sw=4 tw=76 et syntax=python: